// use all the classes provided in package ddf.minim
import ddf.minim.*;
// the minim "manager"
Minim minim;
// the audio clip object
AudioSnippet explode;
AudioSnippet boing;
// animation
Animation anim;
// PFont variable declariation
PFont f;
// Score an Lives
int score= 0;
int lives = 5;
int superbullet = 5;
boolean end = false;
boolean start = false;


// an ArrayList to store the bullets
ArrayList bullets = new ArrayList();
ArrayList sbullets = new ArrayList();
Enemy[] enemy = new Enemy[20];
Stars[] stars = new Stars[200];
Avatar avatar = new Avatar();


void setup() {
  size(600,600);
  colorMode(RGB, 100);
  smooth();
  noCursor();


  // fontloading
  f = loadFont("BankGothic-Light-14.vlw");

  // image loading for avatar
  avatar.img = loadImage("ship.gif");
  avatar.img_l = loadImage("shipl.gif");
  avatar.img_r = loadImage("shipr.gif");
 

  // Create an animation of 2 frames, with a delay of 5
  anim = new Animation("enemy_a_", "gif", 2, 5); 

  // initialize the enemies
  for (int i = 0; i<enemy.length; i++) {
    enemy[i] = new Enemy();

  }
  // initialize the stars
  for (int i = 0; i<stars.length; i++) {
    stars[i] = new Stars();
  }
  
  // initialize the minim
  minim = new Minim(this);
  // load the audio clip
  explode = minim.loadSnippet("ship.wav");
  boing = minim.loadSnippet("explode.wav");
}

void draw() {
  avatar.dir = 0;
  background(0);
  frameRate(30);
  // Text display
  textFont(f, 14);
  fill(255,0,0);
  text ("lost in space - the game",10,15);
  textFont(f, 12);
  text ("highscore:", 10,35);
  text (score,110,35);
  text ("lives:", 10,50);
  text (lives,110,50);
  text ("superbullets:", 10,65);
  text (superbullet,110,65);
  processBullets();
  processSbullets();
  if (keyPressed) {
    if (key == CODED) {
      if(keyCode==UP && avatar.y > 0) {
        avatar.y -= avatar.speed;  
      }
      else if(keyCode==DOWN && avatar.y < height-70) 
        avatar.y += avatar.speed;

      else if(keyCode==LEFT && avatar.x > 10) {
        avatar.x -= avatar.speed;
        avatar.dir = -1; 
      }
      else if(keyCode==RIGHT && avatar.x < height-60) {
        avatar.x += avatar.speed;
        avatar.dir = 1;
      }
    }
  }
  // Avatar on Stage
  avatar.paint();


  // Stars on Stage

  for (int i = 0; i<stars.length; i++) {
    stars[i].move();
    stars[i].paint();
  }

  if (end == false) {
    for (int i = 0; i<enemy.length; i++) {
      enemy[i].move();
      enemy[i].paint();
      // distance between enemy and avatar
      if (dist(enemy[i].x-25,enemy[i].y-25,avatar.x,avatar.y)<=25){
        lives -= 1;
        avatar.x = 275;
        avatar.y = 530;
        enemy[i].x = 2000;
        // sound 
        // only do this if the clip isn't playing
        if (!explode.isPlaying()) {
          // play the clip
          explode.play();
          // rewind the clip
          explode.rewind();
        }

      }
    } 
  } 
  if (lives <=0){
    end = true;
    textFont(f, 30);
    text ("gameover",220,300);
    textFont(f, 12);
    text ("press space to start again",220,320);
    text ("your highscore:", 220,340);
    text (score,340,340);
    anim.paint(width/2-20, height/2-40);
    anim.animate();
    avatar.x = 3000;
    for (int i = 0; i<enemy.length; i++) {
      enemy[i].x = 2000;
 
    } 
    if ((end ==  true) && (key == ' ')) {
      lives += 5;
      if (superbullet >= 0) {
        superbullet = 0;
        superbullet +=5;
      }
      
      score = 0;
      avatar.paint();
      avatar.x = 275;
      end = false;
      for (int i = 0; i<enemy.length; i++) {
      enemy[i].paint();
      enemy[i].reset();
      
        
      }
    }
  }
}


// bullets are processed in a function
void keyPressed() {
  if (key == ' ') {
    Bullet oneBullet = new Bullet();
    oneBullet.x = avatar.x;
    oneBullet.y = avatar.y+10;
    bullets.add(oneBullet);
  }
if (superbullet > 0) {
 if (key == 'x') {
    superbullet -= 1;
    Sbullet oneSbullet = new Sbullet();
    oneSbullet.x = avatar.x+25;
    oneSbullet.y = avatar.y+10;
    sbullets.add(oneSbullet); 
  }  
}
}



// move and draw every bullet in the bullets list
// remove bullets which are offscreen
void processBullets() {
  // for each bullet in the list
  for (int i = 0; i < bullets.size(); ) {

    // get the bullet at index i of the list
    Bullet oneBullet = (Bullet)bullets.get(i);

    // if the bullet is offscreen then remove it from the list
    // BUT don't increase the counting index i
    if (oneBullet.y < 0) {
      bullets.remove(i);
    }

    // else, move and draw the bullet 
    // AND increase the counting index i
    else {
      oneBullet.y -= oneBullet.speed;
      oneBullet.paint();
      i++;
      for (int r = 0; r<enemy.length; r++) {
        // distance between enemy and bullet
        if (dist(enemy[r].x-5,enemy[r].y-5,oneBullet.x,oneBullet.y)<=20){
          score += 10;
          enemy[r].paint();
          enemy[r].reset();
          oneBullet.x = 2000;
          // sound 
          // only do this if the clip isn't playing
          if (!boing.isPlaying()) {
            // play the clip
            boing.play();
            //                      // rewind the clip
            boing.rewind();
          }
        }
      }
    }
  }
}
//Superbullets
// move and draw every bullet in the bullets list
// remove bullets which are offscreen
void processSbullets() {
  // for each bullet in the list
  for (int i = 0; i < sbullets.size(); ) {

    // get the bullet at index i of the list
    Sbullet oneSbullet = (Sbullet)sbullets.get(i);

    // if the bullet is offscreen then remove it from the list
    // BUT don't increase the counting index i
    if (oneSbullet.y < 0) {
      sbullets.remove(i);
    }

    // else, move and draw the bullet 
    // AND increase the counting index i
    else {
      oneSbullet.y -= oneSbullet.speed;
      oneSbullet.paint();
      i++;
      for (int r = 0; r<enemy.length; r++) {
        // distance between enemy and sbullet
        if (dist(enemy[r].x-5,enemy[r].y-5,oneSbullet.x,oneSbullet.y)<=20){
          score += 50;
          enemy[r].paint();
          enemy[r].reset();
          
          
          //oneSbullet.x = 2000;
          // sound 
          // only do this if the clip isn't playing
          if (!boing.isPlaying()) {
            // play the clip
            boing.play();
            //                      // rewind the clip
            boing.rewind();
          }
        }
      }
    }
  }
}

// This function is called by the Processing environment when the sketch is closed
void stop()
{
  // always close Minim audio classes when you are done with them
  boing.close();
  explode.close();
  // always stop Minim before exiting
  minim.stop();
  // calls the original Java Applet Stop() function 
  super.stop();
}